Content

* itsp ch9.06 -

use wagepan, clear
xtset nr year
generate lhours = log(hours)

forvalues y = 1980/1987 {
	quietly {
		eststo clear
		regress lwage educ lhours  if year == `y'
		mfx compute, dyex
		mat eta = e(Xmfx_dyex) \ e(Xmfx_se_dyex)
		eststo, add(eta_educ eta[1, 1] etase eta[2, 1])
		regress lwage educ lhours black hisp if year == `y'
		mfx compute, dyex
		mat eta = e(Xmfx_dyex) \ e(Xmfx_se_dyex)
		eststo, add(eta_educ eta[1, 1] etase eta[2, 1])
		regress lwage educ exper expersq lhours black hisp if year == `y'
		mfx compute, dyex
		mat eta = e(Xmfx_dyex) \ e(Xmfx_se_dyex)
		mat xbar = e(Xmfx_X)
		scalar mu2 = 2 * xbar[1, 2]
		lincom exper + mu2 * expersq
		eststo, addscalars(eta_educ eta[1, 1] etase eta[2, 1] exper r(estimate) se r(se))
 	}
	esttab _all using lwage`y'.tex, replace ti("Wage equations for `y'") ///
	       nomtitles nodepvars not se noobs ar2 booktabs ///
	       scalar(eta_educ etase exper se) ///
	       addnotes("eta_educ: semi-elasticity of lwage with respect to educ" ///
	       "etase: standard error of the semi-elasticity" ///
	       "exper: effect of exper on lwage at mean exper") ///
	       substitute("_cons" "Constant" "eta_educ" "$\eta_{educ}$" ///
	       "etase" "$\eta_{se}$") 
}

separate lwage, by(black | hisp) veryshortlabel
forvalues y = 1981/1987 {
	quietly {
	regress lwage educ exper lhours if year == `y'
	scatter lwage0 lwage1 lhours if year==`y', msize(small) ///
	        scheme(s2mono) nodraw ///
	        name(scat`y',replace) ytitle(lwage) legend(pos(5) ring(0) col(1))
	avplot lhours, msize(small) nodraw scheme(s2mono) name(avplot`y', replace) 
	graph combine scat`y' avplot`y', nodraw col(2) saving(lwage`y', replace) ///
	      ti("Log wage vs. log hours for `y'") 
	}
}

graph use lwage1984