Content

* itsp ch9.01 - ch9.05c

clear all
use grunfeldavg
levelsof company, local(colist)
local ncomp : word count `colist'
forvalues i = 1/`ncomp' {
	local c : word `i' of `colist'
	quietly regress invest L(1/2).kstock L.kapavg if company == `c'
	matrix beta`i' = e(b)
	matrix allbeta = (nullmat(allbeta) \ beta`i')
	local row "`row' `c'"
}
matrix rownames allbeta = `row'
	
outtable using ch9.03t, mat(allbeta) replace ///
format(%9.4f) center caption("Grunfeld company estimates")

use grunfeldavg, clear
levelsof company, local(colist)
local ncomp : word count `colist'
matrix table1 = J(`ncomp', 7, 0)

local i 0
levelsof company, local(colist)
foreach c of local colist {
	quietly {
		local ++i
		summarize invest if company == `c', detail
		matrix table1[`i', 1] = r(p25)
		matrix table1[`i', 2] = r(p50)
		matrix table1[`i', 3] = r(p75)
		correlate invest invavg if company == `c'
		matrix table1[`i', 4] = r(rho)
		correlate kstock kapavg if company == `c'
		matrix table1[`i', 5] = r(rho)
		regress invest L.kstock L.kapavg if company == `c'
		matrix table1[`i', 6] = _b["L.kstock"]
		matrix table1[`i', 7] = _se["L.kstock"]
	}
}
matrix rownames table1 = `colist'
matrix colnames table1 = p25 p50 p75 r_invest r_kap beta_k se_k

/*
tokenize `colist'
forvalues i = 1/`ncomp' {
	quietly {
		summarize invest if company == ``i'', detail
		matrix table1[`i', 1] = r(p25)
		matrix table1[`i', 2] = r(p50)
		matrix table1[`i', 3] = r(p75)
		correlate invest invavg if company == ``i''
		matrix table1[`i', 4] = r(rho)
		correlate kstock kapavg if company == ``i''
		matrix table1[`i', 5] = r(rho)
		regress invest L.kstock L.kapavg if company == ``i''
		matrix table1[`i', 6] = _b["L.kstock"]
		matrix table1[`i', 7] = _se["L.kstock"]
	}
}
matrix rownames table1 = `colist'
matrix colnames table1 = p25 p50 p75 r_invest r_kap beta_k se_k
*/
/*
forvalues i = 1/`ncomp' {
	local c : word `i' of `colist'
	quietly {
		summarize invest if company == `c', detail
		matrix table1[`i', 1] = r(p25)
		matrix table1[`i', 2] = r(p50)
		matrix table1[`i', 3] = r(p75)
		correlate invest invavg if company == `c'
		matrix table1[`i', 4] = r(rho)
		correlate kstock kapavg if company == `c'
		matrix table1[`i', 5] = r(rho)
		regress invest L.kstock L.kapavg if company == `c'
		matrix table1[`i', 6] = _b["L.kstock"]
		matrix table1[`i', 7] = _se["L.kstock"]
	}
}
matrix rownames table1 = `colist'
matrix colnames table1 = p25 p50 p75 r_invest r_kap beta_k se_k
*/

mat list table1, format(%9.3f) ti("Grunfeld company statistics")
outtable using ch9.02t, mat(table1) replace ///
format(%9.3f) center caption("Grunfeld company statistics")

use grunfeldavg, clear
levelsof company, local(colist)
local ncomp : word count `colist'
tempname p
postfile `p' compnr p25 p50 p75 r_invest r_kap beta_k se_k using firmstats, replace

forvalues i = 1/`ncomp' {
	local c : word `i' of `colist'
	quietly {
		summarize invest if company == `c', detail
		local p25 = r(p25)
		local p50 = r(p50)
		local p75 = r(p75)
		correlate invest invavg if company == `c'
		local r_invest = r(rho)
		correlate kstock kapavg if company == `c'
		local r_kap = r(rho)
		regress invest L.kstock L.kapavg if company == `c'
	}
	post `p' (`i') (`p25') (`p50') (`p75') (`r_invest') (`r_kap') ///
	(_b["L.kstock"]) (_se["L.kstock"]) 
}
postclose `p'

use firmstats, clear
summarize

tempname fh
file open `fh' using matout.raw, write replace

local rows = rowsof(table1)
local cols = colsof(table1)
local timestamp "Matrix created `c(current_date)' `c(current_time)'"
file write `fh' "`timestamp'" _n
file write `fh' "`rows' `cols'" _n
forvalues i = 1/`rows' {
	forvalues j = 1/`cols' {
		file write `fh' (table1[`i', `j']) " "
	}
	file write `fh' _n
}
file close `fh'

tempname fh
file open `fh' using matout2.raw, write replace
local rows = rowsof(table1)
local cols = colsof(table1)
local timestamp "Matrix created `c(current_date)' `c(current_time)'"
file write `fh' "`timestamp'" _n
file write `fh' "`rows' `cols'" _n
local coln : colnames table1
local rown : rownames table1
file write `fh' "firmno `coln'" _n
forvalues i = 1/`rows' {
	local rn : word `i' of `rown'
	file write `fh' `"`rn' "'
	forvalues j = 1/`cols' {
		file write `fh' (table1[`i', `j']) " "
	}
	file write `fh' _n
}
file close `fh'

type matout2.raw