Content

* itsp ch5.01 - 5.15

use un, clear
describe
return list
local sb: sortedby
display "dataset sorted by: `sb'"

summarize troop, detail
scalar iqr = r(p75) - r(p25)
display "IQR = " iqr
scalar semean = r(sd) / sqrt(r(N))
display "Mean = " r(mean) " S.E. = " semean

* from http://www.stata-press.com/data/r9/union
use unionT, clear
xtset
return list

ttest age, by(union)
return list

use un, clear
regress deaths duration troop
ereturn list

local regressors: colnames e(b)
display "Regressors: `regressors'"

estat summarize

matrix list e(b)

estat vce

use usairquality, clear
quietly regress so2 temp manuf pop
estimates store model1
quietly regress so2 temp pop wind
estimates store model2
quietly regress so2 temp wind precip days
estimates store model3
quietly regress so2 temp manuf pop wind precip days
estimates store model4
estimates table model1 model2 model3 model4, stat(r2_a rmse) ///
b(%7.3f) se(%6.3g) p(%4.3f) 

estimates table model4 model1 model3 model2, stat(r2_a rmse ll) /// 
b(%7.3g) star label title("Models of sulphur dioxide concentration") 

estimates for model1 model2 model3 model4: test temp = -1.6

estimates replay model1 

forvalues i = 1/4 {
	estimates restore model`i'
	estimates notes: from file `c(filename)' saved `c(filedate)'
	estimates save so2_model`i', replace
}

clear
estimates clear
estimates describe using so2_model3
estimates use so2_model3
estimates store so2_model3
estimates table *

use usairquality,clear
eststo clear
eststo: quietly regress so2 temp manuf pop
eststo: quietly regress so2 temp pop wind
eststo: quietly regress so2 temp wind precip days
eststo: quietly regress so2 temp manuf pop wind precip days
esttab using esttab_example.tex, ar2 label se nostar nodepvars brackets ///
nomtitles title("Models of sulphur dioxide concentration") booktabs ///
alignment(D{.}{.}{-1}) replace

* prep data for illustration of long/wide

use NEstates, clear
keep if inlist(year,1990,1995,2000)
drop dpi*
keep year popCT popMA popRI
order year
xpose,clear
drop in 1
gen str state = "CT" in 1
replace state = "MA" in 2
replace state = "RI" in 3
rename v1 pop1990
rename v2 pop1995
rename v3 pop2000
order state
list, noobs

reshape long pop, i(state) j(year)
list, noobs sepby(state)

/* prep data for reshape, merge, append
use http://fmwww.bc.edu/ec-p/data/wooldridge2k/MATHPNL,clear
xtset year distid
label var year "year"
rename math4 math4score 
rename math7 math7score
keep distid year lunch enrol expp revpp avgsal drop grad math4score math7score staff cpi rexpp
label data "modified mathpnl.dta from Wooldridge (2000)"
save mathpnlLfull,replace

forv y=1992/1998 {
 preserve
 keep if year==`y'
 save mathpnl`y',replace
 restore
}

use mathpnlLfull, clear
keep distid year expp revpp avgsal math4score math7score
keep if inlist(year,1992,1994,1996,1998)
use mathpnlL,clear
xtset distid year, delta(2)
save mathpnlL, replace
reshape wide expp revpp avgsal math4score math7score, i(distid) j(year)
save mathpnlW, replace
*/

use mathpnl_long, clear
describe

xtset
tabulate year

use mathpnl_wide, clear
describe

reshape long expp revpp avgsal math4score math7score, i(distid) j(year)

describe

reshape wide expp revpp avgsal math4score math7score, i(distid) j(year)

use mathpnl1992, clear
append using mathpnl1994
append using mathpnl1996
append using mathpnl1998
label data ""
save mathpnl_appended, replace
describe

* set up dummy dataset for merge

use mathpnl_long,clear
keep distid year
keep if year == 1992
gen int state = uniform() * 50 + 1
drop year
label var state "State code"
label data ""
sort distid
save mathpnl_state, replace
describe

use mathpnl_long, clear
merge distid using mathpnl_state, sort uniqusing 
tab _merge
assert _merge == 3
drop _merge
save mathpnl_longs, replace

* set up datasets for multiple merge
use mathpnl_wide,clear
forv i=1992(2)1998 {
	preserve
	keep distid *`i'
	label data ""
	save mathpnl`i'm, replace
	restore
}

use mathpnl1992m, clear
forvalues y=1994(2)1998 {
	merge distid using mathpnl`y'm, sort unique
	assert _merge == 3
	drop _merge
}
save mathpnlm, replace

use mathpnl_wide, clear
preserve
stack expp1992 avgsal1992 expp1998 avgsal1998, into(expp sal) wide clear
scatter expp1992 expp1998 sal, m(oh x) scheme(s2mono) ///
  title("School District Expenditures vs. Average Salaries")  ///
  xtitle("Average salaries") ytitle("Expenditures") ///
  legend(position(5) ring(0) label(1 "1992") label(2 "1998"))
restore

use mathpnl_long, clear
separate expp, by(year) veryshortlabel
summarize expp*