Content

* ITSP 4.26 -

use hprice2a, clear
regress price nox dist rooms stratio proptax
mfx, eyex

use hprice2a, clear
// run regression
quietly regress price nox dist rooms stratio
// compute appropriate t-statistic  for 95% confidence interval
scalar tmfx = invttail(e(df_r), 0.975)
tempvar y x eyex seyex1 seyex2
foreach v in `y' `x' `eyex' `seyex1' `seyex2'  { // generate variables needed
	qui generate `v' = . 
}
// summarize, detail computes percentiles of stratio
quietly summarize stratio if e(sample), detail 
local pct  1 10 25 50 75 90 99                  
local i = 0
foreach p of local pct {
	local pc`p' = r(p`p')
	local ++i
// set those percentiles into tempvar x
	quietly replace `x' = `pc`p'' in `i'	
}

local i = 0
foreach p of local pct { 
// compute elasticities at those points
   quietly mfx compute, eyex at(mean stratio = `pc`p'')  
   local ++i         
// save predictions at these points in tempvar y
   quietly replace `y' = e(Xmfx_y) in `i'   
// retrieve elasticities
   matrix Meyex = e(Xmfx_eyex)                         
   matrix eta = Meyex[1, "stratio"]             // for the stratio column
   quietly replace `eyex' = eta[1, 1] in `i'    // and save in tempvar eyex 
// retrieve standard errors of the elasticities
   matrix Seyex = e(Xmfx_se_eyex)                     
   matrix se = Seyex[1,"stratio"]              // for the stratio column
// compute upper and lower bounds of confidence interval  
   quietly replace `seyex1' = `eyex' + tmfx*se[1, 1] in `i'  
   quietly replace `seyex2' = `eyex' - tmfx*se[1, 1] in `i'  
}

label variable `x' "Student/teacher ratio (percentiles `pct')" 
label variable `y' "Predicted median house price, dollars"
label variable `eyex' "Elasticity"
label variable `seyex1' "95% c.i."
label variable `seyex2' "95% c.i."
// graph the scatter of elasticities vs. percentiles of stratio
// as well as the predictions with rline 
// and the 95% confidence bands with connected
twoway (scatter `eyex' `x', ms(Oh) yscale(range(-0.5 -2.0)) ylabel(,nogrid)) ///
   (rline `seyex1' `seyex2' `x') ///
   (connected `y' `x', yaxis(2) yscale(axis(2) range(18000 35000))), ///
   ytitle(Elasticity of price v. student/teacher ratio)