Content

clear
use fem2
local anxlevel None Mild Moderate Severe 
display "The defined levels of anxiety are: `anxlevel'"

local count 0
local anxlevel None Mild Moderate Severe 
foreach a of local anxlevel {
   local count  `count' + 1
   display "Anxiety level `count': `a'"
} 

local count 0
local anxlevel None Mild Moderate Severe 
foreach a of local anxlevel {
   local count = `count' + 1
   display "Anxiety level `count': `a'"
} 

local count 0
local anxlevel None Mild Moderate Severe 
foreach a of local anxlevel {
   local count = `count' + 1
   local newlist "`newlist' `count' `a'"
} 
display "`newlist'"

/*
local count 0
local anxlevel None Mild Moderate Severe 
foreach a of local anxlevel {
   display "Anxiety level `++count': `a'"
} 
*/

local anxlevel None Mild Moderate Severe 
local wds: word count `anxlevel'
display "There are `wds' anxiety levels:"
forvalues i = 1/`wds' {
	local wd: word `i' of `anxlevel'
	display "Level `i' is `wd'"
}

local anxlevel None Mild Moderate Severe
tokenize "`anxlevel'"
local wds: word count `anxlevel'
display "There are `wds' anxiety levels:"
forvalues i = 1/`wds' {
	display "Level `i' is ``i''"
}

use fem2, clear
scalar root2 = sqrt(2.0)
generate double rootage = age * root2

use fem2, clear
scalar lb1 = 80
scalar ub1 = 88
scalar lb2 = 89
scalar ub2 = 97
scalar lb3 = 98
scalar ub3 = 109
forvalues i = 1/3 {
	display _n "IQ " lb`i' " - " ub`i'
	tabulate anxiety if inrange(iq, lb`i', ub`i') 
}

generate age2 = age^2
regress weight age age2
matrix b = e(b)
matrix V = e(V)
matrix list b 
matrix list V

matrix accum C = weight age iq, dev nocons
matrix Corr = corr(C)
matrix list Corr

quietly regress weight age age2
matrix V = e(V)
matrix cov = V[1,2]
matrix list cov
matrix cov2 = V["age","age2"]
matrix list cov2

statsmat iq if age < 35, by(anxiety) stat(N mean sd) matrix(iqanx1)
statsmat iq if age >= 35, by(anxiety) stat(N mean sd) matrix(iqanx2)
matrix result = iqanx1, iqanx2 
mat list result, ti("IQ by anxiety score for <35, >=35 years age")