Content

* ITSP 14.3 -

use crspsubset, clear
label def ind 1 Kappa 2 Lambda 3 Nu 4 Xi 5 Tau 6 Upsilon 7 Phi 8 Chi 9 Psi
g hiord=real(substr(string(permno),1,1))
bys cdate hiord: egen retport = mean(ret)
separate retport, by(hiord)
forv i=1/9 {
	bys cdate: egen index`i' = mean(retport`i') 
}
drop retport*
save ch14.3, replace

type maxindcorr.ado

/*
program drop _all
program maxindcorr
    version 10.1
    syntax varlist(numeric), RET(string) FIRMid(string) GEN(string)

* validate new variable names
    confirm new variable `gen'`firmid'
    confirm new variable `gen'max
    confirm new variable `gen'mu
    confirm new variable `gen'n

    tempvar trday
* establish trading day calendar using firmid variable
    bysort `firmid': gen `trday' = _n
    qui tsset `firmid' `trday'
    qui generate `gen'max = .
    qui generate `gen'mu = .
    qui generate `gen'n = .
    qui generate `gen'`firmid' = .
    qui levelsof `firmid'
    local firms `r(levels)'
    local nf : word count `r(levels)'
    forv i = 1/`nf' {
        local fid : word `i' of `firms'
        qui replace `gen'`firmid' = `fid' in `i'
    }
* create varlist of indices..ret
    confirm numeric variable `ret'
    local vl "`varlist' `ret'"	
* pass to Mata routine
    mata: indcorr("`firmid'", "`vl'","`gen'")	
    end
*/

do indcorr.mata

type indcorr.mata

/*
mata: mata clear
version 10.1
mata:
void function indcorr(string scalar ind, 
                      string scalar vn,
                      string scalar newvar)
{
	st_view(ind, ., ind)
	st_view(eye, ., tokens(vn))
	info = panelsetup(ind, 1)
	nf = rows(info)
	nv = cols(eye)
	nv1 = nv-1
	maxc = newvar + "max"
	st_view(highcorr, 1::nf, maxc)
	mu = newvar + "mu"
	st_view(muret, 1::nf, mu)
	enn = newvar + "n"
	st_view(enn, 1::nf, enn)
// compute correlations between index columns and last column (ret)
	for(i = 1; i <= nf; i++) {
		sigma = correlation(panelsubmatrix(eye, i, info))
		ret = sigma[nv,  1::nv1]		
		maxindex(ret, 1, imax, w)
		highcorr[i] = imax	
// calculate mean return and number of quotes for this panel
		z = panelsubmatrix(eye[.,nv], i, info)
		muret[i] = mean(z)
		enn[i] = rows(z)
	}
}
end
*/


use ch14.3, clear
maxindcorr index1-index9, ret(ret) firm(permno) gen(set1)
summarize set1*
gsort -set1mu
label def ind 1 Kappa 2 Lambda 3 Nu 4 Xi 5 Tau 6 Upsilon 7 Phi 8 Chi 9 Psi
label values set1max ind
list set1permno set1mu set1n set1max in 1/50, noobs sep(0)