Content

* ITSP 10.6 -

*use CLquotes, clear
*drop matmy open high low delt delm contr quotedate
*order qmdy cmdy
*rename contract contractcode
*encode contractcode, gen(contract)
*drop contractcode
*generate qm = mofd(qmdy)
*generate cm = mofd(cmdy)
*format settle %7.2f

use crudeoil, clear
list in 1/51, sepby(qmdy)

// identify last day of trading for near contract in each month
bysort qmdy (cmdy): generate near = contract if _n == 1 

// qmdy is the first date when the near contract is no longer quoted
// that minus 3 trading days is the target rollover date
bysort cmdy (qmdy): generate rolldate = qmdy[_n-3] if near[_n] != near[_n-1] 
bysort cmdy (qmdy): generate roll1date = qmdy[_n-4] if near[_n] != near[_n-1] 
bysort cmdy (qmdy): generate nnear = contract if near[_n] != near[_n-1]
// fixup for first obs
replace nnear = . in 1

bysort qm: egen rollover = mean(rolldate)
bysort qm: egen rollover1 = mean(roll1date)
bysort qm: egen nextnear = mean(nnear)

// calculate price series as settle(near) for pre-rollover dates
bysort qm: generate futprice = settle if contract == near & qmdy < rollover
// calculate price series as settle(nnear) for rollover date et seq.
bysort qm: replace futprice = settle if contract==nextnear & qmdy >= rollover
format futprice %9.2f
// calculate return series for the rollover date
bysort qm: generate settleprev = settle if contract == nextnear & qmdy == rollover1
bysort qm: egen sprev = mean(settleprev)
bysort qm: generate double futret = log(settle) - log(sprev) if qmdy == rollover
// drop obs no longer needed, flagged by missing settle
drop if futprice == .
// calc returns for all non-settle dates
sort qmdy
replace futret = log(settle) - log(settle[_n-1]) if missing(futret)

format rollover %td

sort qmdy cmdy
list qmdy contract futprice futret if !missing(futprice) in 1/62,  noobs sepby(qm)