Content

* ITSP 10.2 -

use crspsubseta, clear
label def ind 1 Kappa 2 Lambda 3 Nu 4 Xi 5 Tau 6 Upsilon 7 Phi 8 Chi 9 Psi
qui levelsof hiord, local(indices)
local nind : word count `indices'
qui levelsof permno, local(firms)
local nf : word count `firms'
matrix retcorr = J(`nf', `nind', .)

local n 0
qui gen meanret = .
qui gen ndays = .
local row = `nind' + 1
foreach f of local firms {
	qui correlate index1-index`nind' ret if permno == `f'
	matrix sigma = r(C)
	local ++n
	forvalues i = 1/`nind' {
		matrix retcorr[`n', `i'] = sigma[`row', `i']
	}
	summarize ret if permno == `f', meanonly
	qui replace meanret = r(mean) in `n'
	qui replace ndays = r(N) in `n'
}

//	qui matrix accum Cov = index1-index`nind' ret if permno == `f', noconst dev 
//	matrix sigma = corr(1/r(N) * Cov)

svmat double retcorr
qui egen double maxretcorr = rowmax(retcorr*) 
qui generate highcorr = .
forvalues i = 1/`nind' {
	qui replace highcorr = `i' if maxretcorr == retcorr`i' ///
	& !missing(maxretcorr) 
}

gsort -meanret highcorr 
label values highcorr ind
list permno meanret ndays highcorr in 1/50, noobs sep(0)